!
! Id: demo-otfmap.pako
!     OTFMAP SWTOTAL EXAMPLE,v 1.1.6 2011-07-21 Hans Ungerechts
!
@ demo-rx-spectrometers                     !  demo setup of receivers
!                                           !  and spectrometers
!                                           !  REPLACE WITH YOUR SETUP!
!
SET ANGLE arcsec                            !
!
SWTOTAL                                   - !  to select total power
  /TPHASE        0.5                        !  time per phase (data sample)
!
CALIBRATE                                 - !   
  /AMBIENT                                - !  ambient load
  /COLD                                   - !  cold    load
  /SKY       -500.0 -400.0                - !  sky at offsets -500.0 -400.0
  /SYSTEM       projection                - !  system for SKY offset
  /TCALIBRATE   5.0                         !  time per calibration subscan
!
PAUSE "CALIBRATE OK to start? [c/q]"        !  a chance to check
!
START                                       !  start
!
OTFMAP        -300   -15  300  -15        - !  offsets at start and end of first OTF 
  /CROLOOP      ROR                       - !  subscans: reference-OTF-reference
  /NOTF          4                        - !  number of on-the-fly subscans
  /REFERENCE  -500  -400  projection      - !  offsets of off-source reference
  /STEP          0    10                  - !  step (shift) between OTF subscans
  /SYSTEM       projection                - !  system for offsets
  /TOTF         120.0                     - !  time per on-the-fly subscan
  /TREFERENCE    20.0                     - !  time per off-source reference
  /ZIGZAG                                   !  go back and forth
!
PAUSE "OTFMAP SWTOTAL OK to start? [c/q]"   !  a chance to check
!
START                                       !  start
!
!! Comments:
!! we assume here that the source already has been selected, 
!! see: demo-source
!!
!! /CROLOOP      ROR means that there will be an 
!!               off-source reference subscan (R)
!!               before and after each OTF suscan (O).
!!               Therefore with /NOTF 4 on-the-fly subscans the complete
!!               subscan sequence will be:
!!               R OTF#1 R   R OTF#2 R   R OTF#3 R   R OTF#4 R   
!!               with
!! /CROLOOP      ROOROOR it would be:
!!               R OTF#1       OTF#2   R   OTF#3       OTF#4 R   
!
