!
! Id: demo-otfmap-swfrequency.pako
!     OTFMAP SWFREQUENCY EXAMPLE,v 1.1.11 2011-11-25 Hans Ungerechts
!
@ demo-rx                                   !  demo setup of receivers
!
BACKEND /CLEAR                              !  clear previous backends
BACKEND VESPA 1 0.040 40.0 0.0 E090 hor LI  !  high spectral resolution 
BACKEND VESPA 2 0.040 40.0 0.0 E090 ver LI  !  with VESPA
BACKEND VESPA 3 0.080 80.0 0.0 E230 hor LI 
BACKEND VESPA 4 0.080 80.0 0.0 E230 ver LI 
!                                           !  REPLACE WITH YOUR SETUP!
!
SET ANGLE arcsec                            !
!
!                                           !  setup frequency switching
SWFREQUENCY   -3.9     3.9  /receiver E090  !  for EMIR band E090
SWFREQUENCY  -11.7    11.7  /receiver E230  !  for EMIR band E230
SWFREQUENCY                 /tphase   0.20  !  same for all receivers/bands
!
CALIBRATE                                 - !   
  /AMBIENT                                - !  ambient load
  /COLD                                   - !  cold    load
  /SKY       -600.0   0.0                 - !  sky at offsets -600.0 0.0
  /SYSTEM       projection                - !  system for offset
  /TCALIBRATE   5.0                         !  time per calibration subscan
!
PAUSE "CALIBRATE OK to start? [c/q]"        !  a chance to check
!
START                                       !  start
!
OTFMAP        -300  -300  300 -300        - !  offsets at start and end of first OTF 
  /CROLOOP      O                         - !  only OTF subscans
  /NOTF         4                         - !  number of on-the-fly subscans
  /REFERENCE    no                        - !  no off-source reference subscans
  /STEP          0    10                  - !  step (shift) between OTF subscans
  /SYSTEM       projection                - !  system for offset
  /TOTF         120.0                     - !  time per on-the-fly subscan
  /ZIGZAG                                   !  go back and forth
!
PAUSE "OTFMAP SWFREQUENCY OK to start? [c/q]" !  a chance to check
!
START                                       !  start
!
!! Comments:
!! we assume here that the source already has been selected, 
!! see: demo-source
